Si en los anteriores artículos vimos cómo copiar los nombres de los archivos seleccionados y la ruta del Explorador de archivos, ahora es el turno de copiar el nombre de la carpeta.
Ampliación de las macros anteriores
Si has llegado hasta aquí sin haber leído esos artículos, te recomiendo que eches un vistazo a estos enlaces antes de seguir:
La macro para copiar la ruta la haremos extendiendo la función de la tecla F12 , que fue la empleada para copiar los nombres de archivos o la ruta.
Gráficamente estamos haciendo esto en el Explorador de archivos:
Es decir, que si el puntero del ratón está:
- en la parte superior, F12 copiará la ruta;
- en el panel derecho, F12 copiará los nombres de los archivos seleccionados;
- en el panel izquierdo, F12 copiará el nombre de la carpeta.
⁂
La macro de AutoHotkey
Como en otras ocasiones, te pongo la macro para que te la puedas descargar y luego la analizamos:
La macro completa es la siguiente:
#IfWinActive ahk_exe explorer.exe
F12 up::
MouseGetPos, , , , miControl
controlesParteSuperior := "NetUIHWND1 UIRibbonWorkPane1 ToolbarWindow323 DirectUIHWND1 ToolbarWindow324 ToolbarWindow321 Edit1 UpBand1 DirectUIHWND2"
if (miControl = "DirectUIHWND3")
CopiarNombreArchivosExplorador()
else if InStr(controlesParteSuperior, miControl)
CopiarRutaExplorador()
else if (miControl = "SysTreeView321")
CopiarCarpetaExplorador()
return
CopiarNombreArchivosExplorador()
{
clipboard =
SendInput, {Control Down}c{Control Up}
ClipWait, 0
Clipboard := RegExReplace(Clipboard, "m)^.+\\", "")
Sort, Clipboard
MsgBox, 64, Copiados nombres de archivos, %Clipboard%
}
CopiarRutaExplorador()
{
ControlGetText, ruta, ToolbarWindow323, A
posición := InStr(ruta, ": ")
ruta := SubStr(ruta, posición+2)
Clipboard := ruta
MsgBox, 64, Copiada la ruta actual, %Clipboard%
}
CopiarCarpetaExplorador()
{
clipboard =
SendInput, {Control Down}c{Control Up}
ClipWait, 0
Clipboard := RegExReplace(Clipboard, "m)^.+\\", "")
MsgBox, 64, Copiado nombre de carpeta actual, %Clipboard%
}
#IfWinActive
Donde está incluido el código no solo para copiar el nombre de la carpeta, sino también el de copiar los nombres de archivos y la ruta de la ventana activa del Explorador de archivos.
Te puedes descargar la macro desde este enlace:
⁂
Análisis de la macro de AutoHotkey
El código es casi el mismo que el visto en el artículo Como copiar los nombres de archivos con AutoHotkey ; las únicas diferencias son:
- las líneas añadidas 9 y 10;
- y la función CopiarCarpetaExplorador, que empieza en la línea 32.
En las líneas 9 y 10 se comprueba si el puntero del ratón está sobre el panel izquierdo del Explorador de archivos. Si es así, se ejecuta la función CopiarCarpetaExplorador.
La función CopiarCarpetaExplorador es básicamente la misma que CopiarNombreArchivosExplorador (línea 15), ya vista en el artículo Cómo copiar los nombres de archivos con AutoHotkey. Por eso no vamos a repetir aquí el análisis del código y sí re recomendarte consultar los artículos mencionados al principio.
⁂
Conclusiones de la macro
Con la tecla F12 podrás:
- copiar la ruta si el ratón está en la parte superior de la ventana del Explorador de archivos;
- copiar los nombres de los archivos seleccionados si el ratón está en el panel derecho;
- copiar el nombre de la carpeta si el ratón está en el panel izquierdo.
☛ Fíjate bien: Haces cosas distintas con la misma tecla en función de dónde esté el ratón. Puedes aprovechar este polimorfismo en tus macros de AutoHotkey. Por ejemplo, en esta macro se ejecutan acciones distintas, pero todas cercanas al concepto de Copiar.
☛ No solo eso: Con esta filosofía puedes hacer crecer tu código de AutoHotkey, siendo todo muy nemotécnico, y extender las operaciones de Copiar a otras aplicaciones.
☛ Por si te lo estás preguntando: No, no uso la tecla F12 del teclado para copiar en el Explorador de archivos. Más bien uso uno de los 12 botones de este ratón:
Como ves, 1 solo botón de este ratón para copiar datos en muchas aplicaciones, no solo en el Explorador de archivos.
Más información sobre este ratón, en este artículo: https://www.gonduana.com/raton-utechsmart-venus-para-trabajar/
⁂
Nada más, solo un par de recomendaciones si te interesa leer más sobre AutoHotkey o si quieres estar al tanto de los artículos de Gonduana que continuarán a este:
- Lee los otros artículos de AutoHotkey de este mismo blog. Los tienes todos si filtras por «AutoHotkey» en la nube de etiquetas (columna derecha del blog).
- Suscríbete al boletín del blog, o sígueme en LinkedIn o Twitter (@jssprt). De esta manera, serás el primero en enterarte de la publicación de los artículos.
